00010 *       RETURNS TO "NEWPAGE"

Parse the keyboard and process arrow keys

00020 PARSE   LDA     RFLAG	SDC Directory?
00030         BEQ     NOTRF	If no, then skip
00040         LDA     11,X		Get File Status
00050         BITA    #16		Is this a Directory?
00060         BNE     FLAGED	If no, select inverse ">"
00070         BRA     POINTR	Else select ">"
00080 NOTRF   LDA     11,X		Get File Status
00090         BMI     FLAGED	File "Selected?" inverse ">"
00100 POINTR  LDA     #$7E		Select ">"
00110         BRA     CURSOR	And display cursor
00120 FLAGED  LDA     #$3E		Inverse ">"
00130 CURSOR  STA     ,U		Send cursor to screen
00140 KEYBD   JSR     [$A000]	Read keyboard
00150         BEQ     KEYBD	If no key press then loop
00160         CMPA    #'^		Up Arrow?
00170         BEQ     UP		If yes then process up arrow
00180         CMPA    #10		Down Arrow?
00190         BEQ     DOWN		If Yes the process down arrow
00200         CMPA    #8		Left Arrow?
00210         BEQ     LEFT		If Yes the process left arrow
00220         CMPA    #9		Right Arrow?
00230         BEQ     RIGHT	If yes then process right arrow
00240         CMPA    #$5F		Shifted Up Arrow
00250         BEQ     SHFTUP	If yes, process shift up arrow
00260         CMPA    #'[		Shifted Down Arrow?
00270         BEQ     SHFTDN	If yes, process shift down arrow
00280         RTS			Exit

Up Arrow

00290 UP      BSR     ERASE	Erase Cursor
00300         CMPU    #$410	Top of screen?
00310         BLE     PARSE	If yes, then abort
00320         LEAU    -32,U	Up one row on screen
00330         LEAX    -32,X	Move data pointer back 2 files
00340         BRA     PARSE	Back to beginning

Down Arrow

00350 DOWN    BSR     ERASE	Erase Cursor
00360         CMPU    #$5E0	Bottom of Screen?
00370         BGE     PARSE	If yes, then abort
00380         TFR     X,D		Move Data pointer to accumulator
00390         ADDD    #32		Add 32
00400         CMPD    BUFEND	End of buffer?
00410         BGE     PARSE	If yes, then abort
00420         LEAU    32,U		Down one row on screen
00430         TFR     D,X		Move pointer forward 2 files
00440         BRA     PARSE	Back to beginning

Left Arrow

00450 LEFT    BSR     ERASE	Erase Cursor
00460         CMPU    #$400	Beginning of screen?
00470         BEQ     PARSE	If yes, then abort
00480         LEAU    -16,U	Left 16 characters on Screen
00490         LEAX    -16,X	Move data pointer back 1 file
00500         BRA     PARSE	Back to beginning

Right Arrow

00510 RIGHT   BSR     ERASE	Erase Cursor
00520         CMPU    #$5F0	End of screen?
00530         BEQ     PARSE	If yes, then abort
00540         TFR     X,D		Move Data pointer to accumulator
00550         ADDD    #16		Add 16
00560         CMPD    BUFEND	End of buffer?
00570         LBGE    PARSE	If yes, then abort
00580         LEAU    16,U		Right 16 characters on Screen 
00590         TFR     D,X		Move pointer forward 1 file
00600         JMP     PARSE	Back to beginning

CURSOR

00610 ERASE   LDB     RFLAG	SDC Directory?
00620         BEQ     NOTRF1	If no, then skip
00630         LDB     11,X		Get File Status
00640         BITB    #16		Is it a directory?
00650         BNE     NOTSEL	If yes, select "*"
00660         BRA     PNTER	Else Select Blank
00670 NOTRF1  LDB     11,X		File Selected?
00680         BMI     NOTSEL	If yes, select "*"
00690 PNTER   LDB     #96		Get Blank space
00700         BRA     SETCUR	Go Display
00710 NOTSEL  LDB     #$6A		Select "*"
00720 SETCUR  STB     ,U		Send to screen
00730         RTS			Exit

Shift Up

00740 SHFTUP  LDA     PAGE		Get Current Directory page
00750         LBEQ    KEYBD	If page 0 then abort
00760         DECA			Select previous page
00770         STA     PAGE		Save in current page
00780         JMP     NEWPAG	Return to SuperCopy

Shift Down

00790 SHFTDN  LDD     CURPAG	Get Current page
00800         ADDD    #$200	Add 512
00810         CMPD    BUFEND	End of files buffer?
00820         LBGT    KEYBD	If yes, then abort
00830         INC     PAGE		Select next page
00840         JMP     NEWPAG	Return to SuperCopy

Variables for Parse Routine

00850 BUFEND  FDB     0		End of Files Buffer
00860 PAGE    FCB     0		Directory page
00870 CURPAG  FCB     0		Current file buffer page
 
 
 
 
 
Reads keyboard while directory is displayed on screen.
Up, Down, Left, and Right arrows navigate screen.
Shift Up and Shift Down navigates multiple pages (if more than
     32 files.)

For disks (or disk images) "selected" files are indicated by "*"

While SDC directory is displayed, nested directories are
     indicated by "*"