10 CLEAR1000,&H4000
20 CLS:PRINT:PRINT" THE UTLIMATE AUTO-BOOT UTILITY
30 PRINT"      COPYRIGHT (C)  1997
40 PRINT"              BY
50 PRINT"         CARL ENGLAND
60 PRINT:PRINT:PRINT"INSTRUCTIONS?
70 I$=INKEY$:IFI$="N"THEN400ELSEIFI$<>"Y"THEN70
80 CLS:PRINT"THIS UTILITY WILL MODIFY A DISK SO THAT ANY BASIC PROGRAM (NAMEDAUTOEXEC) WILL AUTOMATICALLY BE LOADED AND RUN WHEN YOU TYPE DIR";
90 PRINT:PRINT"enter TO CONTINUE
100 IFINKEY$<>CHR$(13)THEN100
110 CLS
120 PRINT"YOU MUST HAVE THE AUTOEXEC.BAS  FILE PLUS 7 OTHER FILES ON THE  DISK TO BE MODIFIED (THE OTHER  7 FILES MAY BE BASIC , M/L OR   DATA).  AN EXACT TOTAL OF 8     FILES MUST BE ON THE DISK.      ***caution*** ONLY USE THIS
130 PRINT"PROGRAM ON A BACKUP COPY OF YOURDISK!  THE DIRECTORY WILL BE    SEVERELY MODIFIED AND A BACKUP  OF THE MODIFIED DISK WILL NOT BEPOSSIBLE!
140 PRINT:PRINT"enter TO CONTINUE
150 IFINKEY$<>CHR$(13)THEN150
160 CLS
170 PRINT"AFTER YOU HAVE PREPARED YOUR    DISK CONTAINING THE 8 NECESSARY FILES, YOU WILL RECEIVE PROMPTS TO MAKE THE DISK INTO AN AUTO-  EXECUTABLE DISK. DURING PROMPTS,THE DISK CONTAINING THIS PROGRAMWILL BE THE SOURCE DISK AND THE
180 PRINT"DISK CONTAINING YOUR 8 FILES    WILL BE THE DESTINATION DISK
190 PRINT:PRINT"enter TO CONTINUE
200 I$=INKEY$:IFI$<>CHR$(13)THEN200
400 LINEINPUT"SOURCE DRIVE:";SD$
410 LINEINPUT"DESTINATION DRIVE:";DD$
420 SD=VAL(SD$):DD=VAL(DD$)
460 IFSD=DD THENCLS:LINEINPUT"INSERT SOURCE DISK--PRESS enter";X$
470 PRINT"LOADING FORMAT INFORMATION
480 LOADM"FORMAT:"+SD$
490 IFSD=DD THENLINEINPUT"INSERT DESTINATION DISK--enter";X$
500 PRINT"ARE YOU SURE?
510 I$=INKEY$:IFI$="N"THENSTOPELSEIFI$<>"Y"THEN510
520 PRINT"PRESERVING DIRECTORY INFORMATION
530 DSKI$DD,17,2,A$,B$:DSKI$DD,17,3,C$,E$
540 PRINT"RE-FORMATTING DIRECTORY
550 F=&HF4
560 D$=DD$
570 IFD$<"0"ORD$>"3"THEN560
580 D=PEEK(&HD89D+VAL(D$))
590 T$="17
600 T=VAL(T$)
610 X=PEEK(&H986)AND&HA8'drive status
620 X=X ORD'add drive mask
630 X=X OR32'add double density
640 IFT>21THENX=X OR16'write precompensation
650 X=X OR8'turn on motor
660 POKE&H986,X'save status
670 POKE&HFF40,X'send command
680 EXEC&HA7D1'wait for speed
690 POKE&HFF48,0'restore to track 0
700 EXEC&HA7D1
710 POKE&HFF49,0
720 POKE&HFF4B,T
730 POKE&HFF48,16
740 EXEC&HA7D1
750 POKE&H972+VAL(D$),T'remember track number
760 POKE&HD62C,&HD6
770 POKE&HD62D,&HD3'point to an RTS (D64F)
780 POKE&HD632,64
790 POKE&HD633,0'store data here (0989)
800 POKE&HD63D,F
810 POKE&HD64A,164
820 POKE&HD64C,128
830 IFF<>244THEN860
840 POKE&HD64A,128
850 POKE&HD64C,164
860 EXEC&HD625'entry point
870 POKE&HFF40,0'turn off drives
880 PRINT"RESTORING DIRECTORY INFORMATION
890 DSKO$DD,17,2,A$,B$:DSKO$DD,17,3,C$,E$
900 IFSD=DD THENLINEINPUT"INSERT SOURCE DISK--PRESS enter";X$
910 PRINT"LOADING AUTO-EXEC ROUTINE
920 LOADM"AUTOEXEC:"+SD$
930 IFSD=DD THENLINEINPUT"INSERT DESTINATION DISK--enter";X$
940 PRINT"SAVING AUTO-EXEC ROUTINE TO     DIRECTORY TRACK #4
950 POKE234,3:POKE235,DD:POKE236,17:POKE237,4:POKE238,&H46:POKE239,0:EXEC55135
960 PRINT:PRINT"DISK NOW AUTO-EXECUTES