start		org		$3f00
;******************************************
;KILL IRQ'S
;******************************************
		orcc		#$50
;******************************************
;SETUP DP
;******************************************

		lda		#$3f
		tfr		a,dp
		setdp		$3f
;******************************************
; CLEAR PENDING VSYNC
;******************************************

		lda		$ff02
;******************************************
; SG24
;******************************************
		sta		$ffc5
		sta		$ffc3
;******************************************
; ALTERNATE CSS
;******************************************
		lda		#8
		sta		$ff22
;******************************************
;CLS
;******************************************
		ldx		#$400
		ldd		#$8080
cls		std		,x++
		cmpx		#$400+6144
		bne		cls
;******************************************
; SETUP
;******************************************
		ldx		#coltab
		ldy		#sintab
		lda		#96
		sta		ycount
;******************************************
; SCREEN POINTER
;******************************************

mainloop	
		ldu		#$a00

p1		lda		#$00
		sta		t1+2
p2		lda		#$00
		sta		t2+2


		
;******************************************
; YLOOP
;******************************************

y1loop
p3		lda		#$00
		sta		t3+2
p4		lda		#$00
		sta		t41+1	

t1		lda		>sintab
t2		adda		>sintab
t3		adda		>sintab
		sta		t123+1

xcount		ldb		#32		
;******************************************
; XLOOP
;******************************************
x1loop
t41		lda		#0
		adda		#3
		sta		t41+1
		lda		a,y 	(y=sintab)
t123		adda		#0
		lsra
		lda		a,x	(x=coltab)
		sta		,u+
		decb
		bne		x1loop

;******************************************
; END XLOOP
;******************************************
		inc		t3+2

		lda		t1+2
		adda		#1
		sta		t1+2

		inc		t2+2

		dec		ycount

		bne		y1loop
;******************************************
; END YLOOP
;******************************************

		lda		#96
		sta		ycount

		inc		p1+1

		lda		p2+1
		suba		#2
		sta		p2+1

		lda		p3+1
		adda		#3
		sta		p3+1

		lda		p4+1
		suba		#4
		sta		p4+1

;******************************************
; WAIT FOR VSYNC
;******************************************
ras		lda		$ff03
		bpl		ras
		lda		$ff02
		jmp		mainloop


ycount		fcb		0


		org		$4000

coltab		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80
		fcb		$80,$20,$bf,$ff,$60,$9f,$8f,$df,$ef,$af
		fcb		$af,$ef,$df,$8f,$9f,$60,$ff,$bf,$20,$80


		org		$4300



		fcb		32,32,33,34,35,35,36,37,38,38,39,40,41,41,42,43
		fcb		44,44,45,46,46,47,48,48,49,50,50,51,51,52,53,53
		fcb		54,54,55,55,56,56,57,57,58,58,59,59,59,60,60,60
		fcb		61,61,61,61,62,62,62,62,62,63,63,63,63,63,63,63
		fcb		63,63,63,63,63,63,63,63,62,62,62,62,62,61,61,61
		fcb		61,60,60,60,59,59,59,58,58,57,57,56,56,55,55,54
		fcb		54,53,53,52,51,51,50,50,49,48,48,47,46,46,45,44
		fcb		44,43,42,41,41,40,39,38,38,37,36,35,35,34,33,32

sintab		fcb		32,31,30,29,28,28,27,26,25,25,24,23,22,22,21,20
		fcb		19,19,18,17,17,16,15,15,14,13,13,12,12,11,10,10
		fcb		9,9,8,8,7,7,6,6,5,5,4,4,4,3,3,3
		fcb		2,2,2,2,1,1,1,1,1,1,1,1,1,1,1,1
		fcb		1,1,1,1,1,1,1,1,1,1,1,1,1,2,2,2
		fcb		2,3,3,3,4,4,4,5,5,6,6,7,7,8,8,9
		fcb		9,10,10,11,12,12,13,13,14,15,15,16,17,17,18,19
		fcb		19,20,21,22,22,23,24,25,25,26,27,28,28,29,30,31



		end		start